-odac --env:SSDIR+=/Joachim/Stuecke/Schritte/Tatsache
/*
korrigierte laustärken
*/
sr = 44100
ksmps = 16
nchnls = 2
0dbfs = 1
seed 3
/*********ALLE KLÄNGE***********/
strset 11, "Frau1.aiff"; nicht benutzt weil das klicken doch stört
strset 12, "Frau2.aiff"
strset 13, "Frau3.aiff"
strset 14, "Frau4.aiff"
strset 15, "Frau5.aiff"
strset 16, "Frau6.aiff"
strset 17, "Frau7.aiff"
strset 18, "FrauZitat.aiff"
strset 21, "Mann1.aiff"
strset 22, "Mann2.aiff"
strset 23, "Mann3.aiff"
strset 24, "Mann4.aiff"
strset 25, "Mann5.aiff"
strset 26, "Mann6.aiff"
strset 27, "Mann7.aiff"
strset 28, "MannZitat.aiff"
strset 31, "Schritte1.aiff"
strset 32, "Schritte2.aiff"
strset 33, "Schritte3.aiff"
strset 34, "Schritte4.aiff"
strset 35, "Schritte5.aiff"
strset 36, "Schritte2a.aiff"
strset 37, "Schritte3a.aiff"
/*********FTABLES FÜR KLÄNGE UND KLANGGRUPPEN***********/
;; erstmal elle nummern bis 100
giAlle ftgen 1, 0, -20, -2, 12, 13, 14, 15, 16, 17, 18, 21, 22, 23, 24, 25, 26, 27, 28, 31, 32, 33, 34, 35
giAlleOhnZ ftgen 2, 0, -18, -2, 12, 13, 14, 15, 16, 17, 21, 22, 23, 24, 25, 26, 27, 31, 32, 33, 34, 35
giFrau ftgen 3, 0, -7, -2, 12, 13, 14, 15, 16, 17, 18
giFrauOhnZ ftgen 4, 0, -6, -2, 12, 13, 14, 15, 16, 17
giFrauZ ftgen 5, 0, -2, -2, 18, 18
giMann ftgen 6, 0, -8, -2, 21, 22, 23, 24, 25, 26, 27, 28
giMannOhnZ ftgen 7, 0, -7, -2, 21, 22, 23, 24, 25, 26, 27
giMannZ ftgen 8, 0, -2, -2, 28, 28
giSchritte ftgen 9, 0, -5, -2, 31, 32, 33, 34, 35
gi11 ftgen 11, 0, -2, -2, 11, 11
gi12 ftgen 12, 0, -2, -2, 12, 12
gi13 ftgen 13, 0, -2, -2, 13, 13
gi14 ftgen 14, 0, -2, -2, 14, 14
gi15 ftgen 15, 0, -2, -2, 15, 15
gi16 ftgen 16, 0, -2, -2, 16, 16
gi17 ftgen 17, 0, -2, -2, 17, 17
gi18 ftgen 18, 0, -2, -2, 18, 18
gi21 ftgen 21, 0, -2, -2, 21, 21
gi22 ftgen 22, 0, -2, -2, 22, 22
gi23 ftgen 23, 0, -2, -2, 23, 23
gi24 ftgen 24, 0, -2, -2, 24, 24
gi25 ftgen 25, 0, -2, -2, 25, 25
gi26 ftgen 26, 0, -2, -2, 26, 26
gi27 ftgen 27, 0, -2, -2, 27, 27
gi28 ftgen 28, 0, -2, -2, 28, 28
gi31 ftgen 31, 0, -2, -2, 31, 31
gi32 ftgen 32, 0, -2, -2, 32, 32
gi33 ftgen 33, 0, -2, -2, 33, 33
gi34 ftgen 34, 0, -2, -2, 34, 34
gi35 ftgen 35, 0, -2, -2, 35, 35
gi36 ftgen 36, 0, -2, -2, 36, 36
gi37 ftgen 37, 0, -2, -2, 37, 37
giM1S ftgen 40, 0, -10, -2, 21, 31, 21, 32, 21, 33, 21, 34, 21, 35; Mann 1 und Schritte
giM7S ftgen 41, 0, -10, -2, 27, 31, 27, 32, 27, 33, 27, 34, 27, 35; Mann 7 und Schritte
giM17S ftgen 42, 0, -3, -2, 21, 27, 33; Mann 1, 7 und Schritte 3
giF23S ftgen 43, 0, -8, -2, 12, 31, 13, 32, 12, 34, 13, 35; Frau 2, 3 und Schritte außer 3
giF45S ftgen 44, 0, -8, -2, 14, 31, 15, 32, 14, 34, 15, 35; Frau 4, 5 und Schritte außer 3
giF67S ftgen 45, 0, -8, -2, 16, 31, 17, 32, 16, 34, 17, 35; Frau 6, 7 und Schritte außer 3
giF678S ftgen 46, 0, -8, -2, 16, 31, 17, 32, 18, 34, 18, 35; Frau 6, 7, Zitat und Schritte außer 3
giM234 ftgen 47, 0, -3, -2, 22, 23, 24; Mann 2, 3, 4
giM456 ftgen 48, 0, -3, -2, 24, 25, 26; Mann 4, 5, 6
giM17S5 ftgen 49, 0, -3, -2, 21, 27, 35; Mann 1, 7 und Schritte 5
giM7S5 ftgen 50, 0, -2, -2, 27, 35; Mann 7 und Schritte 5
/*********FTABLES FÜR ZEITWERTE, PAUSEN UND LAUTSTÄRKEN***********/
;101ff und 201ff
giTmvals1 ftgen 101, 0, -3, -2, 1, .25, .5; viertel achtel sechzehntel
giTmvals2 ftgen 102, 0, -3, -2, .5, .25, .125; achtel sechzehntel zweiunddreißigstel
giTmvals3 ftgen 103, 0, -2, -2, 1, 1; nur viertel
giTmvals4 ftgen 104, 0, -2, -2, .5, .25; achtel sechzehntel
giTmvals5 ftgen 105, 0, -2, -2, .25, .125; sechzehntel zweiunddreißigstel
giTmvals6 ftgen 106, 0, -2, -2, .125, .167; zweiunddreißigstel und triolen
giPsvals1 ftgen 201, 0, -3, -2, 2, 1, .5; halbe viertel achtel
giPsvals2 ftgen 202, 0, -2, -2, .5, .5; nur achtel
giVolvals1 ftgen 203, 0, -4, -2, 1, .5, .25, .125; vier lautstärken im abstand von 6 dB
giVolvals2 ftgen 204, 0, -2, -2, 1, 1; alle lautstärken 1
giVolvals3 ftgen 205, 0, -2, -2, 1, .5; zwei lautstärken im abstand von 6 dB
/*********FTABLES FÜR ZEITEN DER SCHRITTE***********/
;300ff
;indx 0 = Metronom, indx 1 = wo solls losgehen, dann die zeiten für die schritte
;bedenke dass ftlen = anzahl der schritte plus diese zwei werte
giSchr1Zeit ftgen 310, 0, -50, -2, 54 , 2 , 0.313 , 1.304 , 2.537 , 3.384 , 4.418 , 5.517 , 6.551 , 7.609 , 8.754 , 9.900 , 10.908 , 12.076 , 12.973 , 14.022 , 15.071 , 16.062 , 17.104 , 18.187 , 19.203 , 20.402 , 21.534 , 22.608 , 23.680 , 24.567 , 25.594 , 26.639 , 27.771 , 28.935 , 29.843 , 30.8 , 31.991 , 33.049 , 34.221 , 35.265 , 36.450 , 37.526 , 38.821 , 39.753 , 41.053 , 42.178 , 43.250 , 44.606 , 45.523 , 46.988 , 47.848 , 48.945 , 50.077 , 51.502
giSchr2Zeit ftgen 320, 0, -43, -2, 69 , 2 , 0.334 , 1.155 , 1.916 , 2.778 , 3.628 , 4.452 , 5.550 , 6.145 , 7.082 , 7.828 , 8.757 , 9.541 , 10.347 , 11.227 , 12.060 , 12.928 , 13.746 , 14.629 , 15.441 , 16.312 , 17.191 , 18.143 , 19.000 , 19.853 , 20.683 , 21.624 , 21.731 , 23.301 , 24.262 , 25.107 , 25.960 , 26.700 , 27.655 , 28.685 , 29.248 , 30.177 , 31.147 , 31.768 , 32.624 , 33.533 , 34.540
giSchr3Zeit ftgen 330, 0, -41, -2, 84 , 2 , 0.520 , 0.990 , 1.765 , 2.371 , 3.065 , 3.648 , 4.255 , 4.986 , 5.608 , 6.232 , 6.870 , 7.369 , 8.043 , 8.586 , 9.201 , 9.889 , 10.374 , 11.038 , 11.645 , 12.164 , 12.690 , 13.456 , 14.045 , 14.585 , 15.168 , 15.827 , 16.437 , 17.032 , 17.572 , 18.202 , 18.782 , 19.392 , 20.039 , 20.573 , 21.185 , 21.864 , 22.413 , 22.950 , 23.615
giSchr4Zeit ftgen 340, 0, -38, -2, 116 , 2 , 0.331 , 0.755 , 1.277 , 1.794 , 2.296 , 2.821 , 3.300 , 3.773 , 4.293 , 4.838 , 5.399 , 5.880 , 6.341 , 6.893 , 7.311 , 7.901 , 8.342 , 8.870 , 9.349 , 9.906 , 10.408 , 10.908 , 11.349 , 11.900 , 12.481 , 12.899 , 13.488 , 13.851 , 14.353 , 14.887 , 15.333 , 15.880 , 16.332 , 16.823 , 17.508 , 17.905
giSchr5Zeit ftgen 350, 0, -34, -2, 176 , 2 , 0.1, 0.5, 1.013 , 1.306 , 1.736 , 2.064 , 2.433 , 2.827 ,3.133 , 3.410 , 3.872 , 4.177 , 4.557 , 4.865 , 5.094 , 5.593 , 5.909 , 6.203 , 6.603 , 6.911 , 7.311 , 7.642 , 8.008 , 8.327 , 8.725 , 9.073 , 9.448 , 9.779 , 10.176 , 10.519 , 10.966 , 11.3
giSchr2aZeit ftgen 360, 0, -80, -2, 76 , 2, 0.342 , 1.027 , 1.869 , 2.653 , 3.471 , 4.174 , 5.050 , 5.822 , 6.5 , 7.401 , 8.214 , 9.015 , 9.810 , 10.649 , 11.413 , 12.251 , 13.047 , 13.909 , 14.617 , 15.392 , 16.241 , 17.029 , 17.818 , 18.582 , 19.403 , 20.175 , 20.901 , 21.719 , 22.500 , 23.333 , 24.117 , 24.8 , 25.655 , 26.445 , 27.252 , 28.073 , 28.810 , 29.669 , 30.433 , 31.187 , 32.090 , 32.819 , 33.643 , 34.406 , 35.161 , 35.961 , 36.705 , 37.483 , 38.206 , 39.076 , 39.828 , 40.670 , 41.413 , 42.231 , 42.963 , 43.781 , 44.507 , 45.331 , 46.043 , 46.843 , 47.681 , 48.425 , 49.148 , 49.972 , 50.846 , 51.551 , 52.364 , 53.1 , 53.859 , 54.648 , 55.505 , 56.308 , 57.000 , 57.858 , 58.642 , 59.476 , 60.308 , 61.106
giSchr3aZeit ftgen 370, 0, -75, -2, 84 , 2, 0.543 , 1.257 , 1.968 , 2.692 , 3.489 , 4.142 , 4.876 , 5.515 , 6.200 , 6.908 , 7.561 , 8.311 , 9.064 , 9.842 , 10.513 , 11.317 , 11.961 , 12.640 , 13.299 , 13.981 , 14.637 , 15.415 , 16.057 , 16.800 , 17.499 , 18.155 , 18.921 , 19.661 , 20.329 , 21.031 , 21.728 , 22.451 , 23.063 , 23.803 , 24.449 , 25.231 , 25.913 , 26.590 , 27.341 , 28.058 , 28.697 , 29.469 , 30.058 , 30.761 , 31.478 , 32.200 , 32.853 , 33.533 , 34.246 , 34.905 , 35.672 , 36.371 , 37.123 , 37.840 , 38.484 , 39.189 , 39.866 , 40.632 , 41.334 , 42.034 , 42.728 , 43.447 , 44.086 , 44.820 , 45.508 , 46.187 , 46.887 , 47.653 , 48.376 , 49.049 , 49.720 , 50.471 , 51.200
opcode TakeAll2, aa, ii
ifil, iskip xin
ichn filenchnls ifil
if ichn == 1 then
aL soundin ifil, iskip
aR = aL
else
aL, aR soundin ifil, iskip
endif
xout aL, aR
endop
opcode RandValFromTab_i, i, ii
/*nimmt einen zufälligen index von einer tabelle und gibt dessen wert heraus.
seed muss auf 0 gesetzt sein, wenn man immer einen neuen startwert will*/
/*input:
itab: die tabelle
itablen: deren länge (normalerweise ftlen; falls 2^n+1, dann ftlen-1)*/
itab, itablen xin
index random 0, itablen - 0.00001
indexn = int(index)
ival tab_i indexn, itab
xout ival
endop
opcode RandTransit, k, iik
/*gibt entweder val 1 oder val 2 heraus, in der wahrscheinlichkeit die von kprob abhängt*/
/*Input:
ival1: Wert 1
ival2: Wert 2
kprob: 0-1. wenn 0, kommt nur val1; wenn 1, nur val2. bei 0.3 hat val1 gegenüber val2 die wahrscheinlichkeit 7:3, usw
*/
ival1, ival2, kprob xin
krand random 0, 1
kwahl = (kprob > krand ? ival2 : ival1)
xout kwahl
endop
instr 1; für beschleunigung bzw verlangsamung
;i1 st dur stdur rel min ft1 ft2 prbst prbend paus1 paus2 vol
idur = p4; Anfangsdauer
irel = p5; verkürzung (<0) oder verlängerung (>0) der dauer bei jedem nachfolgenden ereignis
ilim = p6; kleinster/größter zu erreichender wert
ift1 = p7; ftable 1 mit bestimmten klängen zur auswahl
ift2 = p8; ftable 2
ift1strt = p9; wahrscheinlichkeit (0-1) dass ein klang aus ft1 am anfang kommt (sonst einer aus ft2)
ift1end = p10; wahrscheinlichkeit dass ein klang aus ft1 am ende kommt (zwischen anfang und ende linear)
ipausanf = p11; wahrscheinlichkeit von pausen am anfang
ipausend = p12; und am ende (1=immer 0=nie)
ivol = p13
ifad = .1; fadin/fadout ein zehntel der dauer des schnipsels
kprob linseg ift1strt, p3, ift1end
kpauspr linseg ipausanf, p3, ipausend
kft RandTransit ift2, ift1, kprob; 0 sollte also nur ift2 geben, 1 nur ift1
kft init (ift1strt > 0.5? ift1 : ift2)
kpaus RandTransit 0, 1, kpauspr
kpaus init (ipausanf > 0.5? 1 : 0)
loop:
timout 0, idur, do
reinit loop
do:
ipaus = i(kpaus)
if ipaus == 0 then; nur wenn keine pause wird instr 10 gerufen
ift = i(kft)
iftlen = ftlen(ift)
ifil RandValFromTab_i ift, iftlen
event_i "i", 10, 0, idur, ifil, ifad, ivol
endif
idur = (idur <= ilim ? ilim : idur - (idur * irel))
endin
instr 2; für mischung
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
imetro = p4; metronomangabe für das tempo
itmval = 60 / imetro; dasselbe in sec
itmft = p5; ftable mit den möglichen notenwerten
ipsft = p6; ftable mit den möglichen pausenwerten
ift1 = p7; ftable 1 mit bestimmten klängen zur auswahl
ift2 = p8; ftable 2
ift1strt = p9; wahrscheinlichkeit (0-1) dass ein klang aus ft1 am anfang kommt (sonst einer aus ft2)
ift1end = p10; wahrscheinlichkeit dass ein klang aus ft1 am ende kommt (zwischen anfang und ende linear)
ipausanf = p11; wahrscheinlichkeit von pausen am anfang
ipausend = p12; und am ende (1=immer 0=nie)
ifadanf = p13; wahrscheinlichkeit von fadin/fadout über je die hälfte am anfang
ifadend = p14; und am ende
ivol = p15; globale lautstärke
kprob linseg ift1strt, p3, ift1end
kpauspr linseg ipausanf, p3, ipausend
kfadpr linseg ifadanf, p3, ifadend
kft RandTransit ift2, ift1, kprob; 0 sollte also nur ift2 geben, 1 nur ift1
kft init (ift1strt > 0.5? ift1 : ift2)
kpaus RandTransit 0, 1, kpauspr
kpaus init (ipausanf > 0.5? 1 : 0)
kfad RandTransit 0, 1, kfadpr
kfad init (ifadanf > 0.5? 1 : 0)
itmftlen = ftlen(itmft)
ipsftlen = ftlen(ipsft)
loop:
ipaus = i(kpaus)
if ipaus == 1 then
ipsfac RandValFromTab_i ipsft, ipsftlen
idur = ipsfac * itmval
else
itmfac RandValFromTab_i itmft, itmftlen
idur = itmfac * itmval
endif
timout 0, idur, do
reinit loop
do:
if ipaus == 0 then; nur wenn keine pause wird instr 10 gerufen
ift = i(kft)
iftlen = ftlen(ift)
ifil RandValFromTab_i ift, iftlen
ifad = (i(kfad) == 1 ? .5 : .1); ein- und ausblende entweder hälftig oder ein zehntel
event_i "i", 10, 0, idur, ifil, ifad, ivol
endif
endin
instr 3; für schritte: zählt automatisch weiter, berechnet die nächste pause mit und gibt die anschlusszeit heraus
;i3 st 1 smp nschr nextpaus vol
ismp = p4; strset nummer mit dem jeweiligen schritt-sample
inschr = p5; wieviele schritte sollen gemacht werden
ivol = p7
inextpaus = p6; wieviele pausen kommen danach
itabnr = ismp * 10; ftable mit den zeiten
istartindx tab_i 1, itabnr; in index 1 steht wo's losgeht
if istartindx+inschr > ftlen(itabnr) then
istartindx = 2
endif
iendindx = istartindx + inschr - 1; letzter schritt der noch gemacht wird
if istartindx == 2 then; ermittelung der skiptime
ianftm = 0
else
istartval tab_i istartindx, itabnr
iprevstart tab_i istartindx-1, itabnr
ianftm = istartval - ((istartval - iprevstart) / 2); mitte zwischen startschritt und vorigem schritt
endif
iendval tab_i iendindx, itabnr
ipostendval tab_i iendindx+1, itabnr
iendtm = iendval + ((ipostendval - iendval) / 2); mitte zwischen letztem schritt und schritt danach
p3 = iendtm - ianftm
;berechnung der pause
imetro tab_i 0, itabnr
ischrschn = 60 / imetro
prints "Nächste Zeit: %.3f%n", p2+p3+(inextpaus*ischrschn)
;rausgeben mit fades
ifad = ischrschn / 4; ein viertel des tempos
aL, aR TakeAll2 ismp, ianftm
aL linen aL*ivol, ifad, p3, ifad
aR linen aR*ivol, ifad, p3, ifad
outs aL, aR
tabw_i iendindx+1, 1, itabnr
endin
instr 4; wie instr 2 aber mit ftable als p15 für lautstärken
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
imetro = p4; metronomangabe für das tempo
itmval = 60 / imetro; dasselbe in sec
itmft = p5; ftable mit den möglichen notenwerten
ipsft = p6; ftable mit den möglichen pausenwerten
ift1 = p7; ftable 1 mit bestimmten klängen zur auswahl
ift2 = p8; ftable 2
ift1strt = p9; wahrscheinlichkeit (0-1) dass ein klang aus ft1 am anfang kommt (sonst einer aus ft2)
ift1end = p10; wahrscheinlichkeit dass ein klang aus ft1 am ende kommt (zwischen anfang und ende linear)
ipausanf = p11; wahrscheinlichkeit von pausen am anfang
ipausend = p12; und am ende (1=immer 0=nie)
ifadanf = p13; wahrscheinlichkeit von fadin/fadout über je die hälfte am anfang
ifadend = p14; und am ende
ivoltab = p15; ftable mit lautstärkefaktoren aus denen zufällige ausgewählt wird
kprob linseg ift1strt, p3, ift1end
kpauspr linseg ipausanf, p3, ipausend
kfadpr linseg ifadanf, p3, ifadend
kft RandTransit ift2, ift1, kprob; 0 sollte also nur ift2 geben, 1 nur ift1
kft init (ift1strt > 0.5? ift1 : ift2)
kpaus RandTransit 0, 1, kpauspr
kpaus init (ipausanf > 0.5? 1 : 0)
kfad RandTransit 0, 1, kfadpr
kfad init (ifadanf > 0.5? 1 : 0)
itmftlen = ftlen(itmft)
ipsftlen = ftlen(ipsft)
loop:
ipaus = i(kpaus)
if ipaus == 1 then
ipsfac RandValFromTab_i ipsft, ipsftlen
idur = ipsfac * itmval
else
itmfac RandValFromTab_i itmft, itmftlen
idur = itmfac * itmval
endif
timout 0, idur, do
reinit loop
do:
if ipaus == 0 then; nur wenn keine pause wird instr 10 gerufen
ift = i(kft)
iftlen = ftlen(ift)
ifil RandValFromTab_i ift, iftlen
ivol RandValFromTab_i ivoltab, ftlen(ivoltab)
ifad = (i(kfad) == 1 ? .5 : .1); ein- und ausblende entweder hälftig oder ein zehntel
event_i "i", 10, 0, idur, ifil, ifad, ivol
endif
endin
instr 10
;i10 st dur fil fad vol
ifil = p4
ifad = p5; .5 oder .1
ifad = ifad * p3
ivol = p6
ifilen filelen ifil
iskipmax = ifilen - p3
iskip random 0, iskipmax
aL, aR TakeAll2 ifil, iskip
aL linen aL, ifad, p3, ifad
aR linen aR, ifad, p3, ifad
outs aL*ivol, aR*ivol
endin
instr 11; einzelnes abspielen mit ein paar mehr params als i10
;i 11 st dur fil skip vol fadin fadout
ifil = p4
iskip = p5
ivol = p6; faktor
ifadin = p7
ifadout = p8
aL, aR TakeAll2 ifil, iskip
aL linen aL, ifadin, p3, ifadout
aR linen aR, ifadin, p3, ifadout
outs aL*ivol, aR*ivol
endin
a 0 0 0
#define startfrau1 #0#
#define startfrau2 #91.4#
#define startfrau3 #172.8#
#define startfrau4 #245.8#
#define startfrau5 #308.6#
#define startfrauzitat #356#
#define startmannabs #389.8#
#define startmann1 #0#
#define startmann2 #101#
#define startmann3 #202#
#define startmann4 #285#
#define startmann5 #367#
#define startmannzitat #449#
t 0 60 $startmannabs 60 \
$startmannabs 76 [$startmannabs + $startmann2] 76 \
[$startmannabs + $startmann2] 84 [$startmannabs + $startmann3] 84 \
[$startmannabs + $startmann3] 76 [$startmannabs + $startmann4] 76 \
[$startmannabs + $startmann4] 84
;;;*****************************FRAU*****************************;;;
b $startfrau1
;/********TEIL 1: MM 54********/
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 31 6 3 1.5
i 3 9.4 1 31 4 2 1.5
i 3 15.9 1 31 3 1 1.5
i 3 20.3 1 31 2 5 1.5
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
i 2 28 58 54 201 201 12 12 .5 .5 .5 .5 1 1 2
i 2 86 5.4 54 201 201 12 12 .5 .5 .5 .5 1 1 0; 5 schläge pause (5.4 sec)
b $startfrau2
;/********TEIL 2: MM 69********/ (Start 91.4)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 32 7 4 1.5
i 3 9.3 1 32 4 3 1.5
i 3 15.1 1 32 3 2 1.5
i 3 19.2 1 32 2 5 1.5
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
i 2 25.1 52 69 201 201 13 13 .5 .5 .5 .4 1 1 2
i 2 77.1 4.3 69 201 201 13 13 .5 .5 .5 .4 1 1 0; 5 schläge pause (4.3 sec)
b $startfrau3
;/********TEIL 3: MM 84********/ (Start 172.8)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 33 8 4 1.5
i 3 8.2 1 33 5 3 1.5
i 3 13.4 1 33 3 2 1.5
i 3 16.7 1 33 2 5 1.5
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
i 2 21.7 45.7 84 201 201 14 14 .4 .6 .6 .4 1 1 2
i 2 21.7 45.7 84 201 201 14 14 .4 .6 .6 .4 1 1 2
i 2 69.4 3.6 84 201 201 14 14 .4 .6 .6 .4 1 1 0; 5 schläge pause (3.6 sec)
b $startfrau4
;/********TEIL 4: MM 116********/ (Start 245.8)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 34 9 5 1.5
i 3 7.2 1 34 6 4 1.5
i 3 12.3 1 34 4 3 1.5
i 3 15.8 1 34 3 5 1.5
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
i 2 19.9 40.3 116 201 201 15 15 .4 .6 .5 .3 1 1 1.7
i 2 19.9 40.3 116 201 201 15 15 .4 .6 .5 .3 1 1 1.7
i 2 60.2 2.6 116 201 201 15 15 .4 .6 .5 .3 1 1 0; 5 schläge pause (2.6 sec)
b $startfrau5
;/********TEIL 5: MM 176********/ (Start 308.6)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 35 10 6 1
i 3 5.7 1 35 7 5 1
i 3 9.8 1 35 5 4 1
i 3 12.9 1 35 4 5 1
;i2 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 vol
i 2 16 31.4 176 201 201 16 16 .4 .6 .5 .2 1 1 1.5
i 2 16 31.4 176 101 201 16 16 .4 .6 .5 .2 1 1 1.5
; hinten KEINE pause
b $startfrauzitat
;/********ZITAT MIT VORBEREITUNG********/ (Start 356)
;i1 st dur stdur rel min ft1 ft2 prbst prbend paus1 paus2 vol
i 1 6.8 6.8 .34 .1 .085 17 3 .5 .5 0 .3 1.2
i 1 8.5 5.1 .227 .1 .085 4 3 .7 .3 0 .3 1.2
i 1 9.86 3.74 .17 .1 .085 3 3 .7 .3 0 .3 1.2
i 1 10.88 2.88 .114 .1 .085 4 3 .7 .3 0 .3 1.2
i 1 11.57 2.03 .085 .1 .085 3 3 .7 .3 0 .3 1.2
;i 11 st dur fil skip vol fadin fadout
i 11 20.4 3 18 0 1 0 0
; bei 33.8 weiter
;;;*****************************MANN*****************************;;;
b [$startmannabs + $startmann1]
;********TEIL 1: MM 76********
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 36 8 4 1
i 3 12 1 36 5 3 1
i 3 20 1 36 3 2 1
i 3 25 1 36 2 5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 32 28 76 201 201 21 21 .4 .6 .5 .7 1 1 203
i 4 36 20 76 201 201 21 21 .4 .6 .5 .5 .5 .5 203
;;i10 st dur fil fad vol
i 10 56 16 16 .5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 68 28 76 201 201 21 21 .4 .6 .7 .5 1 1 203
i 4 72 20 76 201 201 21 21 .4 .6 .5 .5 .5 .5 203
i 2 96 5 76 201 201 21 21 .4 .6 .6 .4 1 1 0; 5 schläge pause
b [$startmannabs + $startmann2]
;********TEIL 2: MM 84******** (Beginn Schlag 101)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 37 8 4 1
i 3 12 1 37 5 3 1
i 3 20 1 37 3 2 1
i 3 25 1 37 2 5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 32 28 84 102 101 47 47 .4 .6 .5 .7 1 1 203
i 4 36 20 84 102 101 47 47 .4 .6 .5 .5 .5 .5 203
;;i10 st dur fil fad vol
i 10 56 16 15 .5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 68 28 84 102 101 47 47 .4 .6 .7 .5 1 1 203
i 4 72 20 84 102 101 47 47 .4 .6 .5 .5 .5 .5 203
i 2 96 5 76 201 201 21 21 .4 .6 .6 .4 1 1 0; 5 schläge pause
b [$startmannabs + $startmann3]
;********TEIL 3: MM 76******** (Beginn Schlag 202)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 36 6 3 1
i 3 9 1 36 4 2 1
i 3 15 1 36 3 1 1
i 3 19 1 36 2 5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 26 22.75 76 201 201 49 49 .4 .6 .5 .7 1 1 203
i 4 29 16.75 76 201 201 49 49 .4 .6 .5 .5 .5 .5 203
;;i10 st dur fil fad vol
i 10 45.5 13 14 .5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 55.25 22.75 76 201 201 49 49 .4 .6 .7 .5 1 1 203
i 4 58.25 16.75 76 201 201 49 49 .4 .6 .5 .5 .5 .5 203
i 2 78 5 76 201 201 21 21 .4 .6 .6 .4 1 1 0; 5 schläge pause
b [$startmannabs + $startmann4]
;********TEIL 4: MM 84******** (beginn schlag 285)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 37 6 3 1
i 3 9 1 37 4 2 1
i 3 15 1 37 2 2 1
i 3 19 1 37 2 4 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 25 20 84 102 101 48 48 .4 .6 .5 .7 .5 .5 203
i 4 28 14 84 102 101 48 48 .4 .6 .5 .5 0 0 203
;;i10 st dur fil fad vol
i 10 43.725 12.5 13 .5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 55.25 22.75 84 102 101 48 48 .4 .6 .7 .5 .5 .5 203
i 4 58.25 16.75 84 102 101 48 48 .4 .6 .5 .5 0 0 203
i 2 78 4 84 201 201 21 21 .4 .6 .6 .4 1 1 0; 4 schläge pause
b [$startmannabs + $startmann5]
;********TEIL 5: MM 84******** (beginn 367)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 37 4 4 1
i 3 8 1 37 4 4 1
i 3 16 1 37 4 4 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 24 21 84 201 201 50 50 .4 .6 .5 .7 .5 .5 203
i 4 27 15 84 201 201 50 50 .4 .6 .5 .5 0 0 203
;;i10 st dur fil fad vol
i 10 42 12 12 .5 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 51 21 84 201 201 50 50 .4 .6 .7 .5 .5 .5 203
i 4 54 18 84 201 201 50 50 .4 .6 .5 .5 0 0 203
i 2 78 4 84 201 201 21 21 .4 .6 .6 .4 1 1 0; 4 schläge pause
b [$startmannabs + $startmannzitat]
;********ZITAT MIT VORBEREITUNG******** (beginn 449)
;i3 st 1 smp nschr nextpaus vol
i 3 0 1 37 4 4 1
;i4 st dur metro tmft psft ft1 ft2 prbst prbend paus1 paus2 fad1 fad2 voltab
i 4 9 3.5 84 102 102 27 27 .4 .6 .1 .1 .2 .2 205; 8tel 16tel 23tel
i 4 9 . 84 102 102 27 27 .4 .6 .1 .1 .2 .2 205
i 4 9 . 84 102 102 27 27 .4 .6 .1 .1 .2 .2 205
i 4 9 . 84 102 102 27 27 .4 .6 .1 .1 .2 .2 205
;i 2 13 4 84 201 201 21 21 .4 .6 .6 .4 1 1 0; 4 schläge pause
i 4 17.25 3.75 84 105 105 27 27 .4 .6 .1 .1 .2 .2 205; 16tel und 32tel
i 4 17.25 . 84 105 105 27 27 .4 .6 .1 .1 .2 .2 205
i 4 17.25 . 84 105 105 27 27 .4 .6 .1 .1 .2 .2 205
i 4 17.25 . 84 105 105 27 27 .4 .6 .1 .1 .2 .2 205
i 4 17.25 . 84 105 105 27 27 .4 .6 .1 .1 .2 .2 205
i 4 17.25 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205; schritte 5 als 8tel 16tel
i 4 17.25 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205
;i 2 22 4 84 201 201 21 21 .4 .6 .6 .4 1 1 0; 4 schläge pause
i 4 25.75 4 84 106 106 27 27 .4 .6 .1 .1 .2 .2 205; 32tel und triolen
i 4 25.75 . 84 106 106 27 27 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 106 106 27 27 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 106 106 27 27 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 106 106 27 27 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205; schritte 5 als 8tel 16tel
i 4 25.75 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205
i 4 25.75 . 84 104 104 35 35 .4 .6 .1 .1 .2 .2 205
;6 pause
;i 11 st dur fil skip vol fadin fadout
i 11 36 24 28 0 1 0 0
e
Version: 3
Render: Real
Ask: Yes
Functions: ioObject
Listing: Window
WindowBounds: 772 102 489 475
CurrentView: io
IOViewEdit: On
Options: -b128 -A -s -m167 -R
ioView background {43690, 43690, 32639}